abonbot/modules/rules.pm

use Modern::Perl;
use Data::Dumper;
use Mojo::Base -strict, -signatures, -async_await;
use Mojo::Util;
use Scalar::Util;

use fsa;

our $redis;
our $config;
our $client;
our $commands;
our $kb_menu;
our $abon_client;

##################################################

my $rules = {
  
   logged_out => async sub
   {
     my ($fsa, $line, $info) = @_;
   
     if ($line ne "/start")
     {
       reply($info, _("Для начала работы наберите <b>/start</b>"));
       return "logged_out";
     }

     # Поступила команда /start
     
     # У нас есть uid в автомате? Это значит, что мы прочитали состояние из внешней базы
     return "command" if $fsa->note("uid");
     
     # Проверяем, логинился ли уже пользователь в нашем боте
     my $res = eval { await $client->get_p("client", "/telegram/$info->{id}/client") };
     if ($@)
     {
       if ($@->{code} == 410)
       {
         reply($info, 
           _("Вас приветствует провайдер") . " " . $config->{provider},
           _("Введите номер лицевого счёта или логин")
         );
         
         return "needs_login";
       }
       else
       {
         die $@;
       }
     }

     reply($info, greet($res->{fio}));
     $fsa->note(uid => $res->{uid});
     return "command";
   },
   
   needs_login => sub($fsa, $line, $info)
   {
     $fsa->note(login => $line);
     reply($info, _("Теперь введите пароль"));
     "needs_password";
   },

   needs_password => async sub
   {
      my ($fsa, $line, $info) = @_;
      
      my $res = eval { await $client->post_p("client", "/telegram/client", {login=>$fsa->note("login"), password=>$line, telegram_id=>$info->{id}}) };
      if ($@)
      {
        $fsa->state("logged_out");
        $fsa->delete_note("login");
        die $@;
      }
         
      reply($info, greet($res->{fio}));
      $fsa->note(uid => $res->{uid});
      $fsa->delete_note("login");
      
      "command";
   },  

   command => async sub
   {
     my ($fsa, $line, $info) = @_;
     await do_command($fsa, $line, $info);
     
     $fsa->state; # или все тот же command, или команда установила уже свое состояние
   },
   
   #### Перевод денег
   
   xfer_needs_uid => async sub
   {
     my ($fsa, $target_uid, $info) = @_;
     my $uid = $fsa->note("uid");
     
     $fsa->state("command"); # на случай die
     
     if ($uid==$target_uid)
     {
       reply($info, _("Нельзя перевести деньги себе самому"));
       return "command";
     }
     
     my $res = await $abon_client->get_p($info, "client", "/client/$target_uid");
     
     if ($res->{disabled})
     {
       reply($info, _("Абонент $target_uid отключен"));
       return "command";
     }
     
     my $nick = $res->{fio};
     my @fio = split(/\s+/, $res->{fio});
     if (@fio)
     {
       my $f = shift(@fio);
       $nick = join(" ", (substr($f, 0, 1) . ".", @fio));
     }
     
     reply(
       $info, _("Получатель денег: ") .  $nick,
       "Теперь введите сумму, которую хотите перевести",
     );
     
     $fsa->note(xfer_to => $target_uid);
     return "xfer_needs_amount";
   }, 
   
   xfer_needs_amount => async sub
   {
     my ($fsa, $amount, $info) = @_;
     my $uid = $fsa->note("uid");
     my $to_uid = $fsa->note("xfer_to");
     
     $amount =~ s/,/./g;
     $amount =~ s/[^\d\.]//g;
     my $tmp = $amount;
     my $count = $amount =~ tr/.//;

     if (!$amount || $count>1)
     {
       reply($info, _("Вы ввели неправильную сумму"));
       return "command";
     }
     
     $fsa->note(xfer_amount => $amount);
     reply_with($info, {
         inline_menu => [[
           { text=>_("Подтвердите перевод"), callback_data=>"\x00/transfer" },
         ]]
       },
       sprintf("%.2f %s %s %d", $amount, $config->{currency}->{human}, _(" на счет абонента"), $to_uid),
     );
     
     return "command";
   },
};

sub greet($whom)
{
  my ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) = localtime(time);
  my $greet = $hour>=4 && $hour<=10 ? _("Доброе утро") : $hour>10 && $hour<6 ? _("Добрый день") : _("Добрый вечер");

  "$greet, $whom";
}

######################

sub make_key($id)
{
  return "abonbot-$id";
}

sub save_fsa($fsa, $chatid)
{
  my $key = make_key($chatid);
  say "saving state ", $fsa->state, Dumper $fsa->notes;

  $redis->del($key);
  $redis->hmset($key, %{ $fsa->notes });
  $redis->expire($key, 3600*24);
}

sub make_fsa($chatid, $from)
{
  my $id = make_key($chatid);
  my $notes = { $redis->hgetall($id) };
  if (keys %$notes)
  {
    return fsa->new($rules, $notes->{_state}, $notes); 
  }
  else
  {
    return fsa->new($rules, "logged_out", {});
  }
}

1;